;b_hsqcetf3gpsi
;avance-version (12/01/11)
;(best)-HSQC
;2D H-1/X correlation via double inept transfer
;   using sensitivity improvement
;phase sensitive using Echo/Antiecho-TPPI gradient selection
;with decoupling during acquisition
;using f3 - channel
;with gradients in back-inept
;(use parameterset B_HSQCETF3GPSI)
;
;(A.G. Palmer III, J. Cavanagh, P.E. Wright & M. Rance, J. Magn.
;   Reson. 93, 151-170 (1991) )
;(L.E. Kay, P. Keifer & T. Saarinen, J. Am. Chem. Soc. 114,
;   10663-5 (1992) )
;(J. Schleucher, M. Schwendinger, M. Sattler, P. Schmidt,
;   O. Schedletzky, S.J. Glaser, O.W. Sorensen & C. Griesinger, 
;   J. Biomol. NMR 4, 301-306 (1994) )
;
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=


prosol relations=<triple>


#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>


"p22=p21*2"
"d11=30m"
"d26=1s/(cnst4*4)"

"p29=300u"


"d0=3u"

"in0=inf1/2"


"DELTA1=d26-p29-d16-p41*cnst41-p42*cnst40"
"DELTA2=d26-p19-d16-p42/2"
"DELTA3=d26-p29-d16-p43*cnst43-p42*cnst42"
"DELTA4=p19+d16+de+8u"

#   ifdef LABEL_CN
"DELTA=p43-d0*2-p19-larger(p8,p44)"
#   else
"DELTA=p43-d0*2-p19-p44"
#   endif /*LABEL_CN*/

1 ze
  d11 pl26:f3
2 d11 do:f3
3 d1
  50u UNBLKGRAD

  (p41:sp25 ph1)
  p29:gp3
  d16
  DELTA1 pl3:f3
  (center (p42:sp26 ph1) (p22 ph6):f3 )
  DELTA1
  p29:gp3
  d16
  (p41:sp27 ph2):f1

  p16:gp4
  d16

  (p44:sp30 ph1)

  (p21 ph3):f3
  DELTA
  d0 

#   ifdef LABEL_CN
  (center (p44:sp30 ph7) (p8:sp13 ph1):f2 )
#   else
  (p44:sp30 ph7)
#   endif /*LABEL_CN*/

  d0
  p19:gp1*EA
  d16
  (p22 ph4):f3
  d16

  (p43:sp28 ph1)

  (p21 ph4):f3
  p19:gp5
  d16
  DELTA2
  (center (p42:sp26 ph1) (p22 ph1):f3 )
  DELTA2
  p19:gp5
  d16
  (p21 ph5):f3

  (p43:sp29 ph2)
  p29:gp6
  d16
  DELTA3
  (center (p42:sp26 ph1) (p22 ph1):f3 )
  DELTA3
  p29:gp6
  d16
  (p43:sp28 ph1)
  DELTA4
  (p42:sp26 ph1)
  4u
  p19:gp2
  d16 pl26:f3
  4u BLKGRAD
  go=2 ph31 cpd3:f3
  d11 do:f3 mc #0 to 2 
     F1EA(calgrad(EA) & calph(ph5, +180), caldel(d0, +in0) & calph(ph3, +180) & calph(ph6, +180) & calph(ph31, +180))
exit
   

ph1=0 
ph2=1
ph3=0 2
ph4=0 0 2 2
ph5=1 1 3 3
ph6=0
ph7=0 0 2 2
ph31=0 2 2 0
  

;pl3 : f3 channel - power level for pulse (default)
;sp30: f1 channel - shaped pulse 180 degree (Bip720,50,20.1)
;p16: homospoil/gradient pulse                         [1 msec]
;p19: gradient pulse 2                                 [500 usec]
;p21: f3 channel -  90 degree high power pulse
;p22: f3 channel - 180 degree high power pulse
;p29: gradient pulse 3                                 [300 usec]
;p44: f1 channel - 180 degree shaped pulse for refocussing
;                      Bip720,50,20.1            (200us at 600.13 MHz)
;d0 : incremented delay (2D)                           [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d11: delay for disk I/O                               [30 msec]
;d16: delay for homospoil/gradient recovery
;d26: 1/(4J(NH))
;cnst4: = J(NH)
;cnst19: H(N) chemical shift (offset, in ppm)
;cnst40: compensation of chemical shift evolution during p42
;           Reburp.1000: 0.5
;           compensate to the extend the other delays allow
;cnst41: compensation of chemical shift evolution during p41
;           Pc9_4_90.1000: 0.529
;cnst42: compensation of chemical shift evolution during p42
;           Reburp.1000: 0.5
;cnst43: compensation of chemical shift evolution during p43
;           Eburp2.1000: 0.5
;inf1: 1/SW(N) = 2 * DW(N)
;in0: 1/(2 * SW(N)) = DW(N)
;nd0: 2
;ns: 1 * n
;ds: >= 16
;aq: <= 50 msec
;td1: number of experiments
;FnMODE: echo-antiecho
;cpd3: decoupling according to sequence defined by cpdprg3: garp4.p62
;pcpd3: f3 channel - 90 degree pulse for decoupling sequence


;use gradient ratio:
;  gp 1 : gp 2 : gp 3 : gp 4 : gp 5 : gp6
;    80 :  8.1 :  -13 :   50 :  -33 :  -2

;use gradient ratio

;for z-only gradients:
;gpz1: 80%
;gpz2: 8.1% for N-15
;gpz3: -13%
;gpz4: 50%
;gpz5: -33%
;gpz6: -2%

;use gradient files:   
;gpnam1: SMSQ10.100
;gpnam2: SMSQ10.100
;gpnam3: SMSQ10.32
;gpnam4: SMSQ10.100
;gpnam5: SMSQ10.100
;gpnam6: SMSQ10.32

;sp13:wvm: cawurst-20(280 ppm, 0.5 ms)
;sp25:wvm: pc9(4 ppm, cnst19 ppm)
;sp26:wvm: reburp(4 ppm, cnst19 ppm)
;sp27:wvm: pc9_fb(4 ppm, cnst19 ppm)
;sp28:wvm: eburp2(4 ppm, cnst19 ppm)
;sp29:wvm: eburp2_fb(4 ppm, cnst19 ppm)
;cpd3:wvm: garp1(40 ppm; B1max=3.2 W)
;gp1:wvm: wurst_g(24 G/cm, 600 us)
;gp2:wvm: wurst_g(2.43 G/cm, 600 us)
;gp3:wvm: wurst_g(6.5 G/cm, 300 us)
;gp4:wvm: wurst_g(1 ms, 25 G/cm)
;gp5:wvm: wurst_g(600 us, 16.5 G/cm)
;gp6:wvm: wurst_g(300 us, 1 G/cm)
                                          ;preprocessor-flags-start
;LABEL_CN: for C-13 and N-15 labeled samples start experiment with 
;             option -DLABEL_CN (eda: ZGOPTNS)
                                          ;preprocessor-flags-end



;$Id: b_hsqcetf3gpsi,v 1.4.6.1 2012/01/31 17:56:18 ber Exp $
