;selnogp
;avance-version (21/09/15)
;1D NOESY using selective refocussing with a shaped pulse
;dipolar coupling may be due to noe or chemical exchange.
;
;H. Kessler, H. Oschkinat, C. Griesinger & W. Bermel,
;   J. Magn. Reson. 70, 106 (1986)
;J. Stonehouse, P. Adell, J. Keeler & A.J. Shaka, 
;   J. Am. Chem. Soc 116, 6037 (1994)
;K. Stott, J. Stonehouse, J. Keeler, T.L. Hwang & A.J. Shaka, 
;   J. Am. Chem. Soc 117, 4199-4200 (1995)
;
;$CLASS=HighRes
;$DIM=1D
;$TYPE=
;$SUBTYPE=
;$COMMENT=


#include <Avance.incl>
#include <Grad.incl>


"p2=p1*2"


"d20=d8*0.5-p16-d16"


#   ifdef CALC_SPOFFS
"spoffs2=bf1*(cnst21/1000000)-o1"
#   else
#   endif /*CALC_SPOFFS*/


"acqt0=-p1*2/PI-4u"


1 ze
2 30m
  
#   ifdef FLAG_BLK
  4u BLKGRAD
#   else
  4u  
#   endif /*FLAG_BLK*/

  d1 pl1:f1
  50u UNBLKGRAD
  (p1 ph1):f1
  3u
  p16:gp1
  d16
  p12:sp2:f1 ph2:r
  3u
  p16:gp1
  d16 pl1:f1
  (p1 ph3):f1
  d20
  p16:gp2
  d16
  3u
  (p2 ph4):f1
  3u
  p16:gp2*-1
  d16
  d20

#   ifdef FLAG_BLK
  4u  
#   else
  4u BLKGRAD
#   endif /*FLAG_BLK*/

  (p1 ph5):f1
  go=2 ph31
  30m mc #0 to 2 F0(zd)

#   ifdef FLAG_BLK
  4u BLKGRAD
#   else
  4u  
#   endif /*FLAG_BLK*/

exit


ph1=0 2 
ph2=0 0 1 1 2 2 3 3
ph3=0
ph4=0
ph5=0
ph31=0 2 2 0 


;pl1 : f1 channel - power level for pulse (default)
;sp2: f1 channel - shaped pulse
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p12: f1 channel - 180 degree shaped pulse
;p16: homospoil/gradient pulse                            [1 msec]
;d1 : relaxation delay; 1-5 * T1
;d8 : mixing time
;d16: delay for homospoil/gradient recovery
;d20: d8*0.5 - p16 - d16
;cnst21: chemical shift for selective pulse (offset, in ppm)
;ns: 2 * n, total number of scans: NS * TD0
;ds: 4


;phcor 2 : phasedifference between power levels sp1 and pl1

;choose p12 according to desired selectivity
;the flip-angle is determined by the amplitude
;set O1 on resonance on the multiplet to be excited or use spoffs


;use gradient ratio:    gp 1 : gp 2
;                         15 :   40

;for z-only gradients:
;gpz1: 15%
;gpz2: 40%

;use gradient files:   
;gpnam1: SMSQ10.100
;gpnam2: SMSQ10.100



                                          ;preprocessor-flags-start
;CALC_SPOFFS: automatically calcuate spoffs for selective pulses
;             start experiment with option -DCALC_SPOFFS (eda: ZGOPTNS)
;FLAG_BLK: for BLKGRAD before d1 rather than go
;             option -DFLAG_BLK: (eda: ZGOPTNS)
                                          ;preprocessor-flags-end



;$Id: $
